Esimerkki 4: Yleistä kahden muuttujan riippuvuuden tarkastelua

Tässä FILE MEDIT -sovelluksessa on mahdollista tarkastella minkä tahansa Survon datatiedoston kahta numeerista muuttujaa.

FILE MEDIT sallii tällaisen "aineistosta riippumattoman" esityksen uuden MEDITS_VAR-täsmennyksen avulla, joka määrää, mitkä muuttujat todellisuudessa vastaavat sivuilla esiintyviä muodollisia merkintöjä |X1|,|X2|,|X3|,...

Esim. MEDITS_VARS=Nimi,Pituus,Paino tarkoittaa, että sivustossa |X1| korvataan (kirjaimellisesti) sanalla 'Nimi', |X2| sanalla 'Pituus' ja |X3| sanalla 'Paino'.

Tässä on tyypillisiä käyttötilanteita (aktivoituna määrittelykentästä SM2):

FILE MEDIT DECA,SM2:SM2   / MEDIT_VARS=Name,Javelin,Hurdles

FILE MEDIT KUNNAT,SM2:SM2 / MEDIT_VARS=Kunta,Tulotaso,SYNT

Sivusto SM2 (toimituskentässä SM2) alkaa tästä:

 29 *MEDIT:SM2 SIZE=24,80 PAGES=Sivu1
 30 *
 31 *PAGE Sivu1: SUCRO:MEDITS
 32 *
 33 *|X1|: -
 34 *
 35 *|X2|: -            |X3|: -
 36 *
 37 *Keskiarvo M1: -                M2: -
 38 *  Hajonta S1: -                S2: -
 39 *
 40 *Korrelaatiokerroin R: ##.###
 41 *
 42 :Huomautuksia:
 43 *%1 / %1=|X2|virhe
 44 *%1 / %1=|X3|virhe
 45 *
 46 *<START> data for sucro MEDITS
 47 **GLOBAL* TEST=0
 48 *FILE DEL A.EMF      <ACT>
 49 *REPLACE !,.,C       <ACT>
 50 *GPLOT /FIX 1        <ACT>
 51 */XYSCALE %1,%2,X    <ACT> / %1=$MIN(|X2|) %2=$MAX(|X2|)
 52 *
 53 */XYSCALE %1,%2,Y    <ACT> / %1=$MIN(|X3|) %2=$MAX(|X3|)
 54 *
 55 : Sukroa /XYSCALE on yleistetty siten, että esim. lisäparametrilla X
 56 : se, paitsi valitsee sopivan asteikkomerkinnän, nyt myös kirjoittaa
 57 : valmiin täsmennyksen
 58 : XSCALE=a(b)c
 59 :
 60 : Funktio $MIN(muuttuja) laskee muuttujan pienimmän arvon aineistossa ja
 61 : funktio $MAX(muuttuja) suurimman arvon.
 62 :
 63 *CONTOUR=[VAALEANHARMAA],0.9,0.99 (hajontaellipsit tasoilla 0.9 ja 0.99)
 64 *OUTFILE=A WHOME=0.6*WX,40 WSIZE=0.3*WX,0.3*WY
 65 *GPLOT %1,|X2|,|X3|   <ACT> / %1=<DATA>  tiedoston polkunimi.
 66 *!!!!!!!!!!
 67 *IND=ORDER,%1,%2 POINT=[RED][fill_color(2)],0,10 / %1=$ORDER() %2=$ORDER()
 68 *INFILE=A TOP=1
 69 *GPLOT %1,|X2|,|X3|   <ACT> / %1=<DATA>
 70 *<END> data of sucro MEDITS
 71 *END
 72 *
 73 *Alkuperäisillä muuttujilla maski - katsotaan muuttujan
 74 *tiedostossa olevasta määrittelystä, joka on esim. muotoa (###.#).
 75 *Johdetuille kentille maskia - vastaa tässä FORMAT=#######.##
 76 *
 77 *Johdettujen kenttien määritelmiä:
 78 *Funktio $MEAN(muuttuja) laskee muuttujan keskiarvon,
 79 *funktio $STDDEV(muuttuja) laskee muuttujan keskihajonnan ja
 80 *funktio $CORR(x,y) laskee muuttujien x ja y korrelaatiokertoimen.
 81 *
 82 *M1=$MEAN(|X2|)       M2=$MEAN(|X3|)
 83 *S1=$STDDEV(|X2|)     S2=$STDDEV(|X3|)
 84 * R=$CORR(|X2|,|X3|)
 85 *|X2|_mitta=abs((|X2|-M1)/S1) / havainnon poikkeama keskiarvosta
 86 *V|X2|=if(|X2|_mitta<2)then(0)else(1)
 87 *|X2|virhe=$CLASS(|X2|_luok,V|X2|)
 88 *CLASSIFICATION |X2|_luok:
 89 *0:
 90 *1: Poikkeuksellinen |X2|!
 91 *END
 92 *
 93 *|X3|_mitta=abs((|X3|-M2)/S2)
 94 *V|X3|=if(|X3|_mitta<2)then(0)else(1)
 95 *|X3|virhe=$CLASS(|X3|_luok,V|X3|)
 96 *CLASSIFICATION |X3|_luok:
 97 *0:
 98 *1: Poikkeuksellinen |X3|!
 99 *END (Sivu1 loppuu tähän.)
100 *

Keskiarvo M1: -