Re: VAR RENAME?

[vastaus aiempaan viestiin]

Nähdäkseni yksittäisen nimenvaihdon voi tehdä seuraavalla sukrolla.
Esim.
/REN_VAR 100m IN DECA2 AS M100
vaihtaa muuttujan 100m nimeksi M100 tiedostossa DECA.
Koska 100m on kolmas muuttuja, saman saa tehdyksi nyös komennolla
/REN_VAR #3 IN DECA2 AS M100

-Seppo

Tässä sukron listaus:
*TUTSAVE REN_VAR
/
/ /REN_VAR <old_name> IN <file> AS <new_name> 
/ changes the name of a variable in a Survo data file.
/
*{tempo -1}{init}
- if W1 '=' RETURN then goto E2
/
/ def Wold=W1 Wfile=W3 Wnew=W5
/
*{save stack}{W1=RENAME}{call SUR-SAVE}{del stack}{load stack}
/
- if Wnew '=' {} then goto ERR1
/
*{jump 1,1,1,1}SCRATCH {act}{line start}
/
*{form}/REN_VAR RETURN / to current application
/
*{R}
*CHECK {print Wfile}.SVO{act}{r}{save char W2}
- if W2 '<>' O then goto ERR2
*{R}
/ Get the old true name (if given by #3, for example):
*MINSTAT {print Wfile},CUR+1 / VARS={print Wold} IND=ORDER,1,1{act}{R}
*{d2}{r}{save word Wold}{R}{d}
/
*{ref set 1}FILE STATUS {print Wfile} / VARS={print Wold}{act}
/ Find FIELDS:
+ A: {R}{save word W2}
- if W2 '<>' FIELDS: then goto A
/
*{R}
/ Find old name:
+ B: {next word}{save word W2}
- if W2 '<>' Wold then goto B
/ Type new name:
*        {l8}{print Wnew}
/ Update:
*{ref jump 1}FILE UPDATE{act}{goto E2}
/
+ ERR1: {message}        Usage: /REN_VAR old_name IN data AS new_name@
*{goto E1}
+ ERR2: {message}        Data file not found!@{goto E1}
/
+ E1:
- on key
-   key _: continue
-   wait 300
+ E2: {message}@{W1=RENAME}{call SUR-RESTORE}
+ E: {end}

• REN_VAR - OK (Petri Palmu 20.2.2006 16:14)

Luettelo keskustelunaiheista

Survo-keskustelupalstan (2001-2013) viestit arkistoitiin aika ajoin sukrolla, joka automaattisesti rakensi viesteistä (yli 1600 kpl) HTML-muotoisen sivukokonaisuuden. Vuoden 2013 alusta Survo-keskustelua on jatkettu entistäkin aktiivisemmin osoitteessa forum.survo.fi. Tervetuloa mukaan!